as3corelibのJSON

taro

Aug 13, 2010

こんにちは. taro (@9re)です.

暑い日が続きますね.

今日はas3corelibのJSONライブラリについてちょっとみてみます.

0.93での大きな変更点

JSON.decodeでJSON standardに準拠しないようなJSONもパース出来るようになりました.

JSONDecoderを直接newしているようなアプリケーションではコンストラクタの引数が1から2に変ったので互換性の問題が起きます.

JSONDecoder() Constructor
public function JSONDecoder(s:String, strict:Boolean)
Constructs a new JSONDecoder to parse a JSON string into a native object.

Parameters
s:String -- The JSON string to be converted into a native object
strict:Boolean -- Flag indicating if the JSON string needs to strictly match the JSON standard or not.

では、どのようなjsonがパース出来るようになったのでしょうか. 3だけ注意が必要です(*)

, で終わる配列を許容する
, で終わる連想配列を許容する
エスケープされていない文字(0x00-0x1F)の許容 (*)
16進数のパース
NaNも正しいtoken
nbsp(non breaking space = String.fromCharCode(160))も空白文字として認められる
終端の不要文字の許容

と言われましても・・・ということで、

早速試してみる

それぞれの項目がチェック出来そうな式を並べて書いていきます。

//　, で終わる配列を許容する
test('[1,2,3,]');
//　, で終わる連想配列を許容する
test('{"key":"value",}');
//　エスケープされていない文字(0x00-0x1F)の許容
test('"hi,\nthere!"');
//　16進数のパース 表示は16進数で
test('0xffffff', function(o:int):String { return o.toString(16); } );
//　NaNも正しいtoken 表示はtoString()する
test('NaN', function(o:Number):String { return o + ''; } );
//　nbsp(non breaking space = String.fromCharCode(160))も空白文字として認められる
test(String.fromCharCode(160) + '"nbsp"');
//　終端の不要文字の許容
test('"end"xxx');

function test(json:String, printer:Function = null):void {
    // 表示用の関数がnullならJSON.encodeで表示する
    printer ||= JSON.encode;
    // 元のJSONとstrit mode = falseでdecodeした結果を表示する
    tf.appendText(json + ' => ' + printer(JSON.decode(json, false)) + '\n');
}

これではまだ動かないコードですので、必要な変数の値等を定義します.

Flash IDEをお使いの方は、フレーム・スクリプトにJSONTest()の中身だけを貼りつけると良いでしょう.

import文はどこに書いても良いので、不自然ですがコンストラクタ内に置きました.

package {
  import flash.display.Sprite;
  import flash.text.TextField;
  public class JSONTest extends Sprite {
    public function JSONTest() {
      import com.adobe.serialization.json.JSON;
      // 表示用TextField
      var tf:TextField = new TextField;
      addChild(tf);
      // 表示用関数
      // , で終わる配列を許容する?
      test('[1,2,3,]');
      // , で終わる連想配列を許容する
      test('{"key":"value",}');
      // エスケープされていない文字(0x00-0x1F)の許容
      test('"hi,\nthere!\r\tunescaped characters\"');
      // 16進数のパース 表示は16進数で
      test('0xffffff', function(o:int):String { return o.toString(16); } );
      // NaNも正しいtoken 表示はtoString()する
      test('NaN', function(o:Number):String { return o + ''; } );
      // nbsp(non breaking space = String.fromCharCode(160))も空白文字として認められる
      test(String.fromCharCode(160) + '"nbsp"');
      // 終端の不要文字の許容
      test('"end"xxx');
      // リサイズ
      tf.width = tf.textWidth + 4;
      tf.height = tf.textHeight + 4;

      function test(json:String, printer:Function = null):void {
        // 表示用の関数がnullならJSON.encodeで表示する
        printer ||= JSON.encode;
        // 元のJSONとstrit mode = falseでdecodeした結果を表示する
        tf.appendText(json + ' => ' + printer(JSON.decode(json, false)) + '\n');
      }
    }
  }
}

どのJSONも上手くパースされているようです.