File:1,2-dimethyl-chickenwire2.svg

; Created in LibreOffice 4.2 with this LibreLogo program
 ; Usage: Put this code into an English language document in LibO Writer,
 ; and click on the Start icon of the View»Toolbars»Logo toolbar.
 TO chem s
 FOR i IN s [
 	fs = FONTSIZE
 	corr = 0
 	IF i IN “⁰¹²³⁴⁵⁶⁷⁸⁹⁺⁻” [ corr = fs/8 ]
 	IF i IN “₀₁₂₃₄₅₆₇₈₉” [ corr = -fs/5 ]
 	IF i = “―” [ corr = fs/10 ]
 	FORWARD corr
 	FORWARD i
 	BACK corr
 ]
 END
 
 TO hexagon
 REPEAT 6 [ FORWARD 25 RIGHT 60 ]
 END
 
 TO hexagons n
 REPEAT n [ hexagon PENUP FORWARD 75 PENDOWN ]
 END
 
 TO chickenwire
 hexagons 2
 REPEAT 10 [
 	RIGHT 120 PENUP FORWARD 25 RIGHT 60 PENDOWN
 	hexagons 3
 	RIGHT 120 PENUP FORWARD 2*25 LEFT 60 FORWARD 25 RIGHT 120 PENDOWN
 	hexagons 4
 	PENUP BACK 25*3
 ]
 p = POSITION
 H = HEADING
 PENUP FORWARD 25 LEFT 60
 PENDOWN FORWARD 15 PENUP
 RIGHT 60 FORWARD [-40, -10]
 HEADING 0 chem “H₃C”
 POSITION p
 HEADING H
 FORWARD 25 RIGHT 60 FORWARD 25 LEFT 60
 PENDOWN FORWARD 15 PENUP FORWARD [-8, -1] HEADING 0 chem “CH₃”
 POSITION p
 HEADING H
 RIGHT 120 PENUP FORWARD 25 RIGHT 60 PENDOWN
 hexagons 3
 RIGHT 120 PENUP FORWARD 3*25 RIGHT 60 FORWARD 2*25 PENDOWN
 hexagons 2
 CLOSE
 END
 
 CLEARSCREEN HOME HIDETURTLE
 FONTFAMILY “Nimbus Sans L”
 FONTSIZE 20 PENSIZE 2 PENJOINT “MITER”
 PENUP POSITION [PAGESIZE[0]-50, PAGESIZE[1]/2]
 PENDOWN HEADING 0
 
 PICTURE “1,2-dimethyl-chickenwire2.svg” [
 	chickenwire
 ]