Tcnicas de

UserForm
avanzadas
Anexo del Manual de Programacin
VBA Excel

http://www.ayudaexcel.com
Contenido

Un cuadro de dilogo no modal .................................................................................................... 4

Mostrar un indicador de progreso ................................................................................................ 7
Crear un indicador de progreso independiente ........................................................................ 8
Construir el UserForm indicador de progreso independiente .............................................. 9
Crear los procedimientos de controlador de eventos para el indicador de progreso
independiente ....................................................................................................................... 9
Crear un procedimiento de inicio para un indicador de progreso independiente ............. 11
Cmo funciona el indicador de progreso independiente ................................................... 11
Mostrar un indicador de progreso utilizando un control de pgina mltiple......................... 11
Modificar un UserForm para un indicador de progreso con un control de pgina mltiple
............................................................................................................................................. 12
Insertar el procedimiento UpdateProgress para un indicador de progreso con un control
de pgina mltiple............................................................................................................... 13
Modificar el procedimiento para un indicador de progreso con un control de pgina
mltiple ............................................................................................................................... 13
Cmo funciona un indicador de progreso con un control de pgina mltiple ................... 13
Mostrar un indicador de progreso sin utilizar un control de pgina mltiple ........................ 13
Crear asistentes ........................................................................................................................... 14
Configurar el control de pgina mltiple para el asistente ..................................................... 15
Aadir los botones al UserForm del asistente ........................................................................ 16
Programar los botones del asistente ...................................................................................... 16
Programar dependencias en un asistente .............................................................................. 17
Realizar la tarea con el asistente............................................................................................. 19
Emular la funcin MsgBox ........................................................................................................... 20
Emulacin de MsgBox: el cdigo MiMsgBox........................................................................... 20
Cmo funciona la emulacin de MsgBox ................................................................................ 21
Utilizar la funcin MiMsgBox en la emulacin de MsgBox ..................................................... 22
Un UserForm con controles deslizantes ..................................................................................... 22
Un UserForm sin barra de ttulo.................................................................................................. 24
Simular una barra de herramientas con un UserForm ............................................................... 25
Un UserForm de tamao ajustable ............................................................................................. 27
Controlar varios botones de UserForm con un controlador de eventos .................................... 30
Seleccionar un color en un UserForm ......................................................................................... 33
Mostrar un grfico en un UserForm............................................................................................ 34
Pasos generales para mostrar un grfico en un UserForm ..................................................... 35
Guardar un grfico como archivo gif....................................................................................... 35
Cambiar la propiedad Picture del control de imagen ............................................................. 35
Tcnicas de UserForm avanzadas

Este manual complementa el captulo 11 del Manual de Macros y programacin VBA. Aqu
encontraremos ms ejemplos de UserForms.

Usar UserForm no modales.

Mostrar un indicador de progreso (tres tcnicas).
Crear un asistente (una serie de cuadros de dilogo interactivos).
Crear una funcin que imita a la funcin MsgBox de VBA.
Permitir a los usuarios mover los controles del UserForm.
Controlar varios objetos con un solo controlador de objetos.
Mostrar un UserForm sin barra de titulo.
Simular una barra de herramientas con un UserForm.
Permitir a los usuarios modificar el tamao de un UserForm.
Controlar varios controles con un solo controlador de eventos.
Usar un cuadro de dilogo para seleccionar un color.
Mostrar un grfico en un UserForm.
Mostrar una hoja de clculo completa en un UserForm.

La mayora de estos ejemplos son ms avanzados, pero todos se basan en aplicaciones

prcticas. Sin embargo, incluso los ejemplos que no son tan prcticos muestran tcnicas muy
tiles.

Un cuadro de dilogo no modal

La mayora de los cuadros de dilogo que nos encontramos con cuadros de dilogo modales,
que debemos hacer desaparecer de la pantalla antes de poder realizar cualquier accin con la
aplicacin subyacente. Sin embargo, algunos dilogos son no modales, lo que significa que el
usuario puede seguir trabajando en la aplicacin mientras se muestra el cuadro de dilogo.

Para mostrar un UserForm no modal, utilizamos una instruccin como la siguiente:

UserForm1.Show vbModeless

La palabra vbModeless es una constante integrada que tiene un valor de 0. Por lo tanto la
siguiente instruccin funciona de forma idntica:

UserForm1.Show 0
El siguiente ejemplo muestra un cuadro de dilogo no modal que contiene informacin sobre
la celda activa. Cuando se muestra el cuadro de dilogo, el usuario puede mover el cursor de la
celda, activar otras hojas y realizar otras acciones con Excel.

La clave est en determinar cundo actualizar la informacin del cuadro de dilogo. Para ello,
el ejemplo supervisa dos eventos del libro: SheetSelectionChange y SheetActivate. Estos
procedimientos de control de eventos se encentran en el mdulo de cdigo para el objeto
ThisWorkbook.

Los procedimientos de control de eventos son los siguientes:

Private Sub Workbook_SheetSelectionChange _

(ByVal Sh As Object, ByVal Target As Range)
Call UpdateBox
End Sub

Private Sub Workbook_SheetActivate(ByVal Sh As Object)

Call UpdateBox
End Sub

Estos procedimientos invocan al procedimiento UpdateBox, que se muestra a continuacin:

Sub UpdateBox()
With UserForm1
' Nos aseguramos de que hay una hoja activa
If TypeName(ActiveSheet) <> "Worksheet" Then
.lblFormula.Caption = "N/A"
.lblNumFormat.Caption = "N/A"
.lblLocked.Caption = "N/A"
Exit Sub
End If

.Caption = "Celda: " & ActiveCell.Address(False,

False)
' Formula
If ActiveCell.HasFormula Then
.lblFormula.Caption = ActiveCell.Formula
Else
.lblFormula.Caption = "(ninguna)"
End If
' Formato nmero
.lblNumFormat.Caption = ActiveCell.NumberFormat
' Bloqueada
 .lblLocked.Caption = ActiveCell.Locked
End With
End Sub

El procedimiento UpdateBox cambia el ttulo del UserForm para que muestre la direccin de
la celda activa; despus actualiza los tres controles de etiqueta (lblFormula,
lblNumFormat y lblLocked).

A continuacin se muestran algunos puntos para ayudar a comprender el funcionamiento de

este ejemplo:

El UserForm no es modal para que podamos acceder a la hoja mientras se muestra.

El cdigo de la parte superior del procedimiento se asegura de que la hoja activa es
una hoja de trabajo. Si la hoja no es una hoja de trabajo, se asigna a los controles de
etiqueta el texto N/A.
El libro supervisa la celda activa usando un vevento Selection_Change (que se
encuentra en el mdulo de cdigo de ThisWorkbook).
La informacin se muestra en los controles de etiqueta del UserForm.

El siguiente dibujo muestra una versin mucho ms sofisticada de este ejemplo. Esta versin
contiene un poco ms de informacin adicional acerca de la celda seleccionada. Los usuarios
veteranos de Excel notarn las similitudes con la ventana Info (una funcin que fue eliminada
de Excel hace varios aos).

A continuacin se muestran algunos puntos clave de esta versin ms sofisticada.

El UserForm tiene una casilla de verificacin (Actualizar automticamente). Cuando

esta casilla de verificacin est activada, el UserForm se actualiza automticamente.
Cuando no lo est, el usuario puede pulsar el botn Actualizar para actualizar la
informacin.
El libro utiliza un mdulo de clase para supervisar dos eventos para todos los libros
abiertos: el evento SheetSelectionChange y el evento SheetActivate.
 Como resultado, el cdigo que muestra la informacin de la celda se ejecuta
automticamente cada vez que se producen estas acciones en cualquier libro
(suponiendo que la opcin Actualizar automticamente est activa). Algunas acciones
(como cambiar el formato numrico de la celda) no desencadenan ninguna de estas
acciones. Por lo tanto, el UserForm tambin contiene un botn Actualizar.
El recuento que se muestra para el campo de precedentes y dependientes de la celda
incluye nicamente las celdas de la hoja activa. Esto es una limitacin de las
propiedades Precedents y Dependents.
Como la longitud de la informacin variar, se utiliza cdigo VBA para modificar el
tamao de las etiquetas y espaciarlas verticalmente (y tambin para cambiar la altura
del UserForm si es necesario).

Mostrar un indicador de progreso

Una de las necesidades ms comunes de los programadores de Excel tiene que ver con los
indicadores de progreso. Un indicador de progreso es un grfico parecido a un termmetro
que muestra el progreso de una tarea, como una macro, que tarde mucho en ejecutarse.

La creacin de un indicador de progreso es una tarea relativamente sencilla. En esta seccin se

muestra cmo crear tres tipos de indicadores de progreso para:

Una macro que no se inicia mediante un UserForm (un indicador de progreso

independiente).
Una macro iniciada por un UserForm. En este caso, el UserForm usa el control de
pgina mltiple, que muestra un indicador de progreso mientras se est ejecutando la
macro.
Una macro iniciada por un UserForm. En este caso, se aumenta la altura del UserForm
y el indicador de progreso aparece en la parte inferior del cuadro.

Para utilizar un indicador de progreso tenemos que poder (de alguna manera) calcular cunto
tardar la macro en completar su trabajo. Esto se puede hacer de varias formas, dependiendo
de la macro. Por ejemplo, si la macro escribe datos en celdas (y sabemos el nmero de celdas
que se van a escribir), basta con escribir cdigo que calcule el porcentaje completado. Incluso
si no podemos calcular de forma precesa el proceso de una macro, es una buena idea indicar al
usuario que la macro todava est en ejecucin.

Un indicador de progreso ralentizar un poco la macro debido al esfuerzo extra de tener que
actualizarla. Si la rapidez es absolutamente crucial en nuestro libro, quizs sea mejor renunciar
al indicador de progreso.
Mostrar el progreso en la barra de estado
Un modo simple de mostrer el progreso de una macro es utilizar la barra de estado de Excel.
La ventaja es que es muy fcil de programar. Sin embargo, el inconveniente es que la mayora
de los usuarios no estn acostumbrados a mirar la barra de estado y preferiran algo ms
visual.
Para escribir texto en la barra de estado, utilizamos una instruccin como sta:

Application.StatusBar = Por favor, espere

Por supuesto, se puede actualizar la barra de estado mientras progresa la macro. Por ejemplo,
si tenemos una variable llamada Pct que prepresenta el porcentaje completado, podemos
escribir cdigo que peridicamente ejecute una instruccin como esta:

Application.StatusBar = "Procesando... " & Pct & "% _

completado."

Cuando la macro finaliza, se devuelve la barra de estado a su estado normal con la siguiente
declaracin:

Application.StatusBar = False

Si no restablecemos la barra de estado, continuar mostrndose el mensaje final.

Crear un indicador de progreso independiente

Esta seccin describe cmo configurar un indicador de progreso independiente (es decir, que
no comienza mostrando un UserForm) para mostrar el progreso de una macro. La macro
simplemente deja la hoja en blanco y escribe 20.000 nmeros al azar en un rango de celdas.

Sub GenerateRandomNumbers()
' Inserta nmeros al azar en la hoja activa
Dim Counter As Integer
Const RowMax As Integer = 500
Const ColMax As Integer = 40
Dim r As Integer, c As Integer
Dim PctDone As Single

If TypeName(ActiveSheet) <> "Worksheet" Then Exit Sub

Cells.Clear
Counter = 1
For r = 1 To RowMax
For c = 1 To ColMax
Cells(r, c) = Int(Rnd * 1000)
Counter = Counter + 1
Next c
PctDone = Counter / (RowMax * ColMax)
Call UpdateProgress(PctDone)
Next r
Unload UserForm1
End Sub
Despus de realizar unas pocas modificaciones en la macro, que veremos en la siguiente
seccin, el UserForm mostrar su progreso.

Construir el UserForm indicador de progreso independiente

Seguiremos estos pasos para crear el UserForm que se utilizar para mostrar el progreso de la
tarea:

1. Insertamos un nuevo UserForm y cambiamos su propiedad Caption a Progreso.

2. Aadimos un control de macro y los llamamos MarcoProgreso.
3. Aadimos un control de etiqueta dentro del marco y lo llamamos LabelProgress.
Eliminamos el ttulo de la etiqueta y hacemos que su color de fondo (BackColor) sea
rojo. El tamao de la etiqueta y su colocacin no son importantes por el momento.
4. Aadimos otra etiqueta sobre el marco para describir qu est pasando (opcional).
5. Configuramos el UserForm y los controles para que aparezcan como en el dibujo.

Por supuesto, podemos aplicar cualquier otro tipo de formato a los controles. Por ejemplo, se
puede cambiar la propiedad SpecialEffect del control de marco que aparece en el dibujo
anterior.

Crear los procedimientos de controlador de eventos para el indicador de progreso

independiente
En este caso, el truco consiste en ejecutar un procedimiento automticamente cuando se
muestra el UserForm. Una manera de hacerlo es utilizar el evento Initialize. Sin
embargo, este evento tiene lugar antes de que el UserForm se muestre realmente, por lo que
no nos resulta til. Por otro lado, el evento Activate se desencadena cuando se muestra el
UserForm, por lo que es perfecto para esta aplicacin.

Insertamos el siguiente procedimiento en la ventana de cdigo del UserForm. Este

procedimiento simplemente invoca a un procedimiento llamado
GenerateRandomNumbers cuando se muestra el UserForm. Este procedimiento, que se
almacena en un mdulo VBA, es la macro que se ejecuta realmente mientras se muestra el
indicador de progreso.

Private Sub UserForm_Activate()

Call GenerateRandomNumbers
End Sub

A continuacin se muestra el procedimiento GenerateRandomNumbers, que vimos

anteriormente, con algunas modificaciones. Observamos que el cdigo adicional realiza un
seguimiento del progreso y lo almacena en una variable llamada PctDone.

Sub GenerateRandomNumbers()
' Inserta nmeros al azar en la hoja activa
Dim Counter As Integer
Const RowMax As Integer = 500
Const ColMax As Integer = 40
Dim r As Integer, c As Integer
Dim PctDone As Single

If TypeName(ActiveSheet) <> "Worksheet" Then Exit Sub

Cells.Clear
Counter = 1
For r = 1 To RowMax
For c = 1 To ColMax
Cells(r, c) = Int(Rnd * 1000)
Counter = Counter + 1
Next c
PctDone = Counter / (RowMax * ColMax)
Call UpdateProgress(PctDone)
Next r
Unload UserForm1
End Sub

El procedimiento GenerateRandomNumbers contiene dos bucles. Dentro del bucle central

hay una llamada al procedimiento UpdateProgress. Este procedimiento toma un
argumento: la variable PctDone, que representa el progreso de la macro. PctDone tendr
un valor entre 0 y 100.

Sub UpdateProgress(Pct)
With UserForm1
.FrameProgress.Caption = Format(Pct, "0%")
.LabelProgress.Width = Pct * (.FrameProgress. _
Width - 10)
.Repaint
End With
End Sub
Crear un procedimiento de inicio para un indicador de progreso independiente
Todo lo que falta es un procedimiento que muestre el UserForm. Introducimos el siguiente
procedimiento en un mdulo VBA:

Sub ShowUserForm()
With UserForm1
.LabelProgress.BackColor = ActiveWorkbook.Theme. _
ThemeColorScheme.Colors(msoThemeAccent1)
.LabelProgress.Width = 0
.Show
End With
End Sub

Cmo funciona el indicador de progreso independiente

Cuando ejecutamos el procedimiento ShowUserForm, se establece que la anchura del
objeto Label sea 0. Despus, el mtodo Show del objeto UserForm1 muestra el UserForm
(que es el indicador de progreso). Cuando se muestra el UserForm, se desencadena su evento
Activate, lo que ejecuta el procedimiento GenerateRandomNumbers. Este
procedimiento contiene el cdigo que invoca al procedimiento UpdateProgress cada vez
que el contador de la variable del bucle r se actualiza. Observamos que el procedimiento
UpdateProgress utiliza el mtodo Repaint del objeto UserForm. Sin esta instruccin, no
se actualizaran los cambios de la etiqueta. Antes de que finalice el procedimiento, la ltima
declaracin descarga el UserForm.

Para personalizar esta tcnica, tendremos que averiguar cmo determinar el porcentaje
completado y asignrselo a la variable PctDone. Esto variar dependiendo de la aplicacin. Si
el cdigo se ejecuta en un bucle (como en este ejemplo), determinar el porcentaje completado
es sencillo. Si el cdigo no est en un bucle, quizs tengamos que calcular el progreso
completado en varios puntos del cdigo.

Mostrar un indicador de progreso utilizando un control de pgina

mltiple
En el ejemplo anterior, la macro no estaba iniciada por un UserForm. En muchos casos, una
macro que tarda mucho en ejecutarse se inicia cuando el usuario hace clic en el botn Aceptar
de un UserForm. La tcnica descrita en esta seccin ser una solucin ms adecuada y
presupone lo siguiente:

El proyecto est completo y sin errores.

El proyecto utiliza un UserForm (sin controles de pgina mltiple) para iniciar una
macro que tarda mucho en ejecutarse.
Hay un modo de calcular el progreso de la macro.

Como en el ejemplo previo, ste introduce nmeros aleatorios en una hoja. La diferencia es
que esta aplicacin contiene un UserForm donde el usuario puede especificar la cantidad de
filas y columnas en las que insertar los nmeros aleatorios.
Modificar un UserForm para un indicador de progreso con un control de pgina
mltiple
Este paso presupone que existe un UserForm completamente configurado. Aadiremos un
control de pgina mltiple. La primera pgina del control de pgina mltiple contendr todos
los controles originales. La segunda contendr los controles que muestran el indicador de
progreso. Cuando la macro comience a ejecutarse, el cdigo VBA cambiar la propiedad
Value del control de pgina mltiple. Esto ocultar efectivamente los controles originales y
mostrar el indicador de progreso.

El primer paro es aadir un control de pgina mltiple a un UserForm. A continuacin,

movemos todos los controles del UserForm y los copiamos en la pgina 1 del control de pgina
mltiple.

El siguiente paso es activar la pgina 2 y configurarla como la que se puede ver en el siguiente
dibujo. Es bsicamente la misma combinacin de controles utilizados en el ejemplo de la
seccin anterior.

1. Aadimos un control de marco y lo llamamos FrameProgress.

2. Aadimos un control de etiqueta y lo llamamos LabelProgress. Eliminamos el
ttulo de la etiqueta y hacemos que su fondo se a de color rojo.
3. Aadimos otra etiqueta para describir qu est pasando (opcional).
4. El siguiente paso es activar el control de pgina mltiple (no una pgina del control) y
asignar a su propiedad Style el valor 2 fbTabStyleNone (esto ocultar las
etiquetas). El modo ms fcil de seleccionar el control de pgina mltiple es utilizar la
lista desplegable de la ventana Propiedades. Probablemente tendremos que ajustar el
tamao del control de pgina mltiple para tener en cuenta que las etiquetas no estn
visibles.
Insertar el procedimiento UpdateProgress para un indicador de progreso con un
control de pgina mltiple
Insertamos el siguiente procedimiento en el mdulo de cdigo del UserForm:

Sub UpdateProgress(Pct)
With UserForm1
.FrameProgress.Caption = Format(Pct, "0%")
.LabelProgress.Width = Pct * (.FrameProgress. _
Width - 10)
End With
DoEvents
End Sub

Este procedimiento se invoca desde la macro que se ejecuta cuando el usuario hace clic en el
botn Aceptar, y realiza la actualizacin del indicador de progreso.

Modificar el procedimiento para un indicador de progreso con un control de pgina

mltiple
Tendremos que modificar el procedimiento que se ejecuta cuando el usuario hace clic en el
botn Aceptar (el procedimiento de control del evento Click para el botn, llamado
OK_Click). En primer lugar, insertamos la siguiente instruccin en la parte superior del
procedimiento:

MultiPage1.Value = 1

Esta instruccin activa la pgina 2 del control de pgina mltiple (la pgina que muestra el
indicador de progreso).

En el siguiente paso, todo depender mucho ms del programador. Quizs haya que escribir
cdigo que calcule el porcentaje completado y asigne este valor a una variable llamada
PctDone. Este clculo se realizar dentro de un bucle. Despus se insertar la siguiente
instruccin, actualizando el indicador de progreso:

Call UpdateProgress(PctDone)

Cmo funciona un indicador de progreso con un control de pgina mltiple

Esta tcnica es muy sencilla y, como hemos visto, slo usa un UserForm. El cdigo intercambia
pginas del control de pgina mltiple y convierte un cuadro de dilogo normal en un
indicador de progreso. Como en las fichas de la pgina mltiple estn ocultas, ni siquiera se
parece a un control de pgina mltiple.

Mostrar un indicador de progreso sin utilizar un control de pgina

mltiple
El ejemplo de esta seccin es similar al ejemplo de la anterior. Sin embargo, esta tcnica es
ms simple porque no utiliza un control de pgina mltiple. En lugar de eso, el indicador de
progreso se almacena en la parte inferior del UserForm (pero se reduce la altura del UserForm
de forma que los controles del indicador de progreso no sean visibles). Cuando hay que
mostrar el indicador de progreso, se incrementa la altura del UserForm, lo que hace que se vea
el indicador de progreso.
El dibujo siguiente muestra el UserForm en el editor de Visual Basic. La propiedad Height del
UserForm es 172. Sin embargo, antes de que aparezca, el valor de Height cambia a 124 (lo
que significa que los controles del indicador de progreso no estn visibles para el usuario).
Cuando el usuario hace clic en Aceptar, el cdigo VBA cambia la propiedad Height a 172
utilizando la siguiente instruccin:

Me.Height = 172

Crear asistentes

Muchas aplicaciones incorporan asistentes para ayudar a los usuarios en alguna operacin. El
asistente para importar texto de Excel es un buen ejemplo. Un asistente es bsicamente una
serie de cuadros de dilogo que solicitan informacin del usuario. A menudo, las elecciones del
usuario en los primeros cuadros de dilogo influyen en los contenidos de los siguientes
cuadros de dilogo. En la mayora de los asistentes, el usuario puede avanzar o retroceder en
la secuencia de cuadros de dilogo o hacer clic en el botn Finalizar para aceptar todos los
valores predeterminados.

Por supuesto, podemos crear asistentes utilizando VBA y series de UserForms. Sin embargo, el
modo ms eficiente de crear un asistente es utilizar un nico UserForm y un control de pgina
mltiple con las fichas ocultas. El siguiente dibujo muestra un ejemplo de un simple asistente
de cuatro pasos que consta de un nico UserForm que contiene un control de pgina mltiple.
Cada paso del asistente muestra una pgina diferente del control de pgina mltiple.

Configurar el control de pgina mltiple para el asistente

Comenzamos con un nuevo UserForm y aadimos un control de pgina mltiple. Por defecto,
este control contiene dos pgina. Hacemos clic con el botn derecho del ratn en la ficha de la
pgina mltiple e insertamos suficientes pginas nuevas para controlar el asistente (una
pgina por cada paso del asistente). El ejemplo que le mostramos es un asistente de cuatro
pasos, de modo que el control de pgina mltiple tendr cuatro pginas. Los nombres de las
fichas de la pgina mltiple no son importantes. La propiedad Style del control tendr un valor
final de 2 fmTabStyleNone. Mientras trabajamos con el UserForm querremos
mantener las fichas visibles para hacer ms fcil acceder a las diferentes pginas.

A continuacin, aadimos los controles deseados para cada pgina del control de pgina
mltiple. Por supuesto, esto variar dependiendo de la aplicacin. Puede que tengamos que
cambiar el tamao del control de pgina mltiple mientras trabajamos para tener espacio para
los controles.
Aadir los botones al UserForm del asistente
A continuacin aadiremos los botones que controlen el progreso del asistente. Estos botones
se colocan fuera del control de pgina mltiple porque se usan mientas se muestra cualquiera
de las pginas. La mayora de los asistentes tienen cuatro botones:

Cancelar: Cancela el asistente.

Anterior: Vuele al paso previo. Durante el Paso 1 del asistente, este botn debe estar
deshabilitado.
Siguiente: Avanza al siguiente paso. Durante el ltimo paso, este botn debe estar
deshabilitado.
Finalizar: Finaliza el asistente.

En el ejemplo, estos botones de comando se llaman CancelButton, BackButton,

NextButton y FinishButton.

En algunos casos, el usuario puede hacer clic en el botn Finalizar en cualquier momento y
aceptar los valores predeterminados para aquellos elementos que el usuario no ha definido.
En otros casos, el asistente necesita una respuesta del usuario para algunos elementos. En ese
caso, el botn Finalizar se deshabilita hasta que se realicen todas las entradas necesarias.

Programar los botones del asistente

Cada uno de los cuatro botones del asistente necesita
un procedimiento para controlar su evento Click. A
continuacin se muestra el control de eventos para
CancelButton. Este procedimiento utiliza una
funcin MsgBox para verificar que el usuario quiere
salir realmente. Si el usuario hace clic en el botn S, el
UserForm se descarga sin tomar ninguna accin. Por
supuesto, este tipo de comprobacin es opcional.

Private Sub CancelButton_Click()

Dim Msg As String
Dim Ans As Integer
Msg = "Cancelar el asistente?"
Ans = MsgBox(Msg, vbQuestion + vbYesNo, APPNAME)
If Ans = vbYes Then Unload Me
End Sub

Los procedimientos de control de eventos para los botones Atrs y Siguiente son los
siguientes:

Private Sub BackButton_Click()

MultiPage1.Value = MultiPage1.Value - 1
UpdateControls
End Sub
Private Sub NextButton_Click()
MultiPage1.Value = MultiPage1.Value + 1
UpdateControls
End Sub
Estos dos procedimientos son muy simples. Cambian la propiedad Value del control de
pgina mltiple y despus invocan a otro procedimiento llamado UpdateControls (que se
muestra a continuacin). El procedimiento UpdateControls se encarga de habilitar y
deshabilitar los controles BackButton y NextButton.

Sub UpdateControls()
Select Case MultiPage1.Value
Case 0
BackButton.Enabled = False
NextButton.Enabled = True
Case MultiPage1.Pages.Count - 1
BackButton.Enabled = True
NextButton.Enabled = False
Case Else
BackButton.Enabled = True
NextButton.Enabled = True
End Select

' Actualiza el ttulo

Me.Caption = APPNAME & " Paso " _
& MultiPage1.Value + 1 & " de " _
& MultiPage1.Pages.Count

' El campo Nombre es obligatorio

If tbName.Text = "" Then
FinishButton.Enabled = False
Else
FinishButton.Enabled = True
End If
End Sub
El procedimiento cambia el ttulo del UserForm para mostrar el paso en el que se encuentra y
el nmero total de pasos. APPNAME es una constante pblica definida en Module1. A
continuacin, examina el campo del nombre de la primera pgina (un cuadro de texto llamado
tbName ). Este es un campo necesario, de modo que no se puede hacer clic en el botn
Finalizar. Si el cuadro de texto est vaco, se deshabilita FinishButton; en caso contrario,
se habilita.

Programar dependencias en un asistente

En la mayora de los asistentes, una respuesta del usuario en un determinado paso puede
afectar a lo que se muestra en el siguiente paso. Los botones de opcin para la valoracin de
un producto slo estarn visibles si el usuario indica un determinado producto.

A efectos de programacin, esto se consigue supervisando el evento Change del control de

pgina mltiple. Cada vez que se cambia el valor de la pgina mltiple (haciendo clic en los
botones Atrs o Siguiente), se ejecuta el procedimiento MultiPage1_Change. Si el control
de pgina mltiple est en la ltima ficha (Paso 4), el procedimiento examina los valores de los
controles de casilla de verificacin del paso 3 y realiza los ajustes apropiados en el paso 4.

En este ejemplo, el cdigo utiliza dos matrices de controles, uno para los controles de casilla
de verificacin (paso 3) y otro para los controles de marco (paso 4). El cdigo utiliza un bucle
For-Next para ocultar los controles de los productos que no se utilizan y ajusta su posicin
vertical. Si ninguna de las casillas de verificacin del paso 3 est marcada, se ocultan todos los
elementos del paso 4 excepto un cuadro de texto que muestra Haz clic en Finalizar para salir (si
no se introdujo un nombre en el paso1) o Se requiere un nombre para el paso 1 (si no se
introdujo un nombre en el paso 1). El procedimiento MultiPage1_Change aparece a
continuacin:

Private Sub MultiPage1_Change()

Dim TopPos As Integer
Dim FSpace As Integer
Dim AtLeastOne As Boolean
Dim i As Integer

' Actualizar pgina de puntuaciones

If MultiPage1.Value = 3 Then
' Crea un array con casillas de verificacin
Dim ProdCB(1 To 3) As MSForms.CheckBox
Set ProdCB(1) = cbExcel
Set ProdCB(2) = cbWord
Set ProdCB(3) = cbAccess

' Crea un array con controles de marco

Dim ProdFrame(1 To 3) As MSForms.Frame
Set ProdFrame(1) = FrameExcel
Set ProdFrame(2) = FrameWord
Set ProdFrame(3) = FrameAccess

TopPos = 22
FSpace = 8
AtLeastOne = False

' Bucle por todos los productos

For i = 1 To 3
If ProdCB(i) Then
ProdFrame(i).Visible = True
ProdFrame(i).Top = TopPos
TopPos = TopPos + ProdFrame(i).Height + _
FSpace
AtLeastOne = True
Else
ProdFrame(i).Visible = False
End If
Next i

' No usa productos?

If AtLeastOne Then
lblHeadings.Visible = True
Image4.Visible = True
lblFinishMsg.Visible = False
Else
lblHeadings.Visible = False
Image4.Visible = False
lblFinishMsg.Visible = True
If tbName = "" Then
lblFinishMsg.Caption = _
"Se requiere un nombre para el paso 1."
 Else
lblFinishMsg.Caption = _
"Haz clic en Finalizar para salir."
End If
End If
End If
End Sub

Realizar la tarea con el asistente

Cuando el usuario hace clic en el botn Finalizar, el asistente realiza su tarea: transferir la
informacin desde el UserForm a la siguiente fila vaca de la hoja. Este procedimiento, llamado
FinishButton_Click, es muy claro. Comienza determinando la siguiente fila vaca de la
hoja y asignando a este valor una variable (r). El resto del procedimiento simplemente traslada
los valores de los controles e introduce datos en la hoja.

Private Sub FinishButton_Click()

Dim r As Long

r = Application.WorksheetFunction. _
CountA(Range("A:A")) + 1

' Insertar el nombre

Cells(r, 1) = tbName.Text

' Insertar el sexo

Select Case True
Case obMale: Cells(r, 2) = "Masculino"
Case obFemale: Cells(r, 2) = "Femenino"
Case obNoAnswer: Cells(r, 2) = "Desconocido"
End Select

' Insertar productos

Cells(r, 3) = cbExcel
Cells(r, 4) = cbWord
Cells(r, 5) = cbAccess

' Insertar puntuaciones

If obExcel1 Then Cells(r, 6) = ""
If obExcel2 Then Cells(r, 6) = 0
If obExcel3 Then Cells(r, 6) = 1
If obExcel4 Then Cells(r, 6) = 2
If obWord1 Then Cells(r, 7) = ""
If obWord2 Then Cells(r, 7) = 0
If obWord3 Then Cells(r, 7) = 1
If obWord4 Then Cells(r, 7) = 2
If obAccess1 Then Cells(r, 8) = ""
If obAccess2 Then Cells(r, 8) = 0
If obAccess3 Then Cells(r, 8) = 1
If obAccess4 Then Cells(r, 8) = 2

Unload Me

End Sub
Tras probar el asistente y comprobar que todo parece funcionar correctamente, podemos
establecer el valor para la propiedad Style del control de pgina mltiple a 2
fmTabStyleNone.

Emular la funcin MsgBox

La funcin MsgBox de VBA es un poco diferente porque, a diferencia de la mayora de las

funciones, muestra un cuadro de dilogo. Pero, al igual que las dems funciones, tambin
devuelve un valor: un nmero entero que representa en qu botn hizo clic el usuario.

Este ejemplo estudia una funcin personalizada que emula la funcin MsgBox de VBA. Al
principio, crear tal funcin puede parecer bastante fcil, pero no es del todo cierto. La funcin
MsgBox es extraordinariamente verstil gracias a los argumentos que acepta. Por tanto, crear
una funcin que emule MsgBox no es una tarea fcil.

La clave de este ejercicio no es crear una funcin alternativa que muestre mensajes. La clave
es mostrar cmo desarrollar una funcin relativamente compleja que tambin incorpora un
UserForm. Sin embargo, a algunas personas les puede gustar la idea de ser capaces de
personalizar sus mensajes. En ese caso, descubrirn que esta funcin es muy fcil de
personalizar. Por ejemplo, pueden cambiar las fuentes, los colores, el botn de texto y
elementos similares.

Hemos llamado a esta funcin que emula a MsgBox MiMsgbox. La emulacin no es

perfecta. MiMsgBox tiene las siguientes limitaciones:

No admite el argumento Helpfile (que aade un botn Ayuda, el cual, cuando se

hace clic sobre l, abre un archivo de ayuda).
No admite el argumento Context (que especifica la identidad del contexto para el
archivo de ayuda).
No admite la opcin de sistema modal, que detiene todos los procesos de Windows
hasta que se responde al cuadro de dilogo.

La sintaxis pata MiMsgBox es:

MiMsgBox (mensaje [, botones] [, ttulo])

Esta sintaxis es exactamente igual que la sintaxis de MsgBox, excepto que no utiliza los dos
ltimos argumentos opcionales (Helpfile y Context). MsgBox tambin utiliza las mismas
constantes predefinidas que MsgBox: vbOkOnly, vbQuestion, vbDefaultButton1 y similares.

Emulacin de MsgBox: el cdigo MiMsgBox

La funcin MiMsgBox usa un UserForm llamado MyMsgBoxForm. La funcin en s misma,
que se muestra a continuacin, es muy corta. La mayor parte del trabajo se hace en el
procedimiento UserForm_Initialize.
 Function MiMsgBox(ByVal prompt As String, _
Optional ByVal buttons As Integer, _
Optional ByVal title As String) As Integer
Prompt1 = prompt
Buttons1 = buttons
Title1 = title
MiMsgBoxForm.Show
MiMsgBox = UserClick
End Function

A continuacin se muestra el cdigo utilizado para ejecutar la funcin:

prompt = "Est a punto de formatear su disco duro."

prompt = prompt & vbCrLf & vbCrLf & "Desea continuar?"
buttons = vbQuestion + vbYesNo
title = "Existe un problema"
Ans = MiMsgBox(prompt, buttons, title)

Por supuesto, este ejemplo no borrar nuestro disco duro.

Cmo funciona la emulacin de MsgBox

Hay que destacar el uso de cuatro variables Public. Las tres primeras (Prompt1,
Buttons1 y Title1) representan los argumentos que se pasan a la funcin. La otra variable
(UserClick) representa los valores devueltos por la funcin. El procedimiento
UserForm_Initialize necesita un modo de obtener esta informacin y enviarla de
nuevo a la funcin, y la nica forma de hacer esto es utilizar la variable Public.

El UserForm que aparece a continuacin contiene cuatro controles de imagen (uno para cada
uno de los posibles iconos), tres controles de botn de comando y un control de cuadro de
texto.

El cdigo del procedimiento UserForm_Initialize examina los argumentos y hace lo

siguiente:

Determina qu imagen (si la hay) se mostrar (y oculta las otras).

Determina qu botn (o botones) se muestra (y oculta los otros).
 Determina qu botn es el botn predeterminado.
Centra los botones en el cuadro de dilogo.
Determina los ttulos de los botones de comando.
Determina la posicin del texto dentro del cuadro de dilogo.
Determina el ancho del cuadro de dilogo (utiliza una llamada API para obtener la
resolucin del vdeo).
Determina la altura que debe tener el cuadro de dilogo.
Muestra el UserForm.

Se incluyen otros tres procedimientos de control de eventos (uno para cada botn de
comando). Estas rutinas determinan en qu botn se hizo clic y devuelven un valor para la
funcin asignando un valor a la variable UserClick.

Interpretar el segundo argumento (buttons) es un poco ms complicado. Este argumento

puede estar formado por varias constantes aadidas juntas. Por ejemplo, el segundo
argumento puede ser algo as:

vbYesNoCancel + vbQuestion + vbDefaultButton3

Este argumento crea un MsgBox con tres botones (S, No y Cancelar), muestra el icono de
pregunta y hace que el tercer botn sea el botn predeterminado. El argumento real es 547 (3
+ 32 + 512).

El objetivo era obtener tres fragmentos de informacin a partir de un nico nmero. La

solucin implica convertir el argumento en un nmero binario y despus examinar los bits
especficos. Por ejemplo, el equivalente binario de 547 es 1000100011. Los dgitos binarios de
4 a 6 determinan la imagen que se muestra, los dgitos de 8 a 10 determinan qu botones
mostrar y los dgitos de 1 y 2 determinan qu botn es el botn predeterminado.

Utilizar la funcin MiMsgBox en la emulacin de MsgBox

Para utilizar esta funcin en nuestros propios proyectos, exportamos el mdulo
MiMsgBoxMod y el UserForm MyMsgBoxForm. A continuacin, importamos estos dos
archivos al proyecto. Despus podremos utilizar la funcin MiMsgBox en nuestro cdigo
como lo haramos con la funcin MsgBox.

Un UserForm con controles deslizantes

A pesar de las reducidas aplicaciones prcticas de esta tcnica, el ejemplo de esta seccin nos
ayudar a comprender los eventos relacionados con el ratn. El UserForm que se muestra a
continuacin contiene tres controles de imagen. El usuario puede utilizar el ratn para
arrastrar las imgenes por el cuadro de dilogo.
Cada uno de los tres controles de imagen tiene dos procedimientos de eventos asociados:
MouseDown y MouseMove. El procedimiento de evento para el control Image1 se muestra
a continuacin (los dems controles de imagen son idnticos a este, excepto por el nombre de
cada control):

Private Sub Image1_MouseDown(ByVal Button As Integer, _

ByVal Shift As Integer, ByVal X As Single, ByVal _
Y As Single)
' Posicin de inicio cuando se presiona el botn
OldX = X
OldY = Y
Image1.ZOrder 0
End Sub

Private Sub Image1_MouseMove(ByVal Button As Integer, _

ByVal Shift As Integer, ByVal X As Single, ByVal _
Y As Single)
' Mueve la imagen
If Button = 1 Then
Image1.Left = Image1.Left + (X - OldX)
Image1.Top = Image1.Top + (Y - OldY)
End If
End Sub

Cuando se hace clic con el botn del ratn, tiene lugar el evento MouseDown, y se guardan las
posiciones X e Y del cursor. Se utilizan dos variables pblicas para hacer un seguimiento de la
posicin original de los controles: OldX y OldY. Este procedimiento tambin modifica la
propiedad ZOrder, que coloca la imagen sobre las otras.
Cuando se mueve el ratn, el evento MouseMove ocurre repetidamente. El procedimiento del
evento comprueba el botn del ratn. Si el argumento Button es 1, significa que el botn
izquierdo del ratn est presionado. En este caso, el control de imagen se mueve en relacin a
su antigua posicin.

Tambin, observamos que el cursor cambia cuando est sobre la imagen. Esto se debe a que la
propiedad MousePointer es 15 fmMousePointSizeAll. Este estilo de cursor se
utiliza comnmente para indicar que algo se puede mover.

Un UserForm sin barra de ttulo

Excel no ofrece ninguna manera de mostrar directamente un UserForm sin barra de ttulo.
Pero este reto es posible con la llamada de algunas nuevas funciones API. El siguiente dibujo
muestra un UserForm sin barra de ttulo.

Otro ejemplo de UserForm sin barra de ttulo se ofrece en el dibujo siguiente. Este cuadro de
dilogo contiene un control de imagen y un control de botn de comando.

Para mostrar un UserForm sin barra de ttulo necesitamos cuadro funciones API:
GetWindowLong, SetWindowLong, DrawMenuBar, y FindWindowA. El procedimiento
UserForm_Initialize invoca estas funciones:

Private Sub UserForm_Initialize()

Dim lngWindow As Long, lFrmHdl As Long
lFrmHdl = FindWindowA(vbNullString, Me.Caption)
lngWindow = GetWindowLong(lFrmHdl, GWL_STYLE)
lngWindow = lngWindow And (Not WS_CAPTION)
Call SetWindowLong(lFrmHdl, GWL_STYLE, lngWindow)
Call DrawMenuBar(lFrmHdl)
End Sub
Un problema de no mostrar la barra de ttulo, es que el usuario no tiene forma de cambiar la
posicin del cuadro de dilogo. La solucin es utilizar los eventos MouseDown y MouseMove,
descritos en la seccin anterior.

Simular una barra de herramientas con un UserForm

La creacin de barras de herramientas en las versiones anteriores a Excel 2007 era

relativamente fcil. Con Excel 2007 es imposible. Para ser exactos, es posible crear una barra
de herramientas personalizada con VBA, pero Excel 2007 ignora muchas de las instrucciones
VBA. En Excel 2007, todas las barras de herramientas personalizadas se muestran en el grupo
Barras personalizadas, de la ficha Complementos. Estas barras de herramientas no se pueden
mover, cambiar de tamao, ni acoplar.

Esta seccin describe cmo crear una barra de herramientas alternativa: un UserForm no
modal que simula una barra de herramientas flotante. El siguiente dibujo muestra un
UserForm que puede sustituir a una barra de herramientas.

El UserForm contiene ocho controles de imagen, y cada uno de ellos ejecuta una macro.
Al ver, en el editor de Visual Basic, el UserForm en modo Diseo, podremos observar que:

Los controles no estn alineados

El UserForm no es el tamao final.
El tamao de la barra de ttulo es estndar.

El cdigo VBA se encarga de la apariencia. Alinea los controles y ajusta la imagen del UserForm
para que no se malgaste ningn espacio, adems, el cdigo emplea funciones API de Windows
para reducir el tamao de la barra de ttulo, justo como una barra de herramientas de verdad.
Para hacer que el UserForm se parezca todava ms a una barra de herramientas,
estableceremos la propiedad ControlTipText de cada control de imagen. Esto har que se
muestre informacin sobre la herramienta similar a la de una barra de herramientas cada vez
que pasemos el cursor sobre ese control.

Si abrimos el archivo correspondiente a este ejemplo, de los adjuntos al manual, tambin

observaremos que las imgenes cambian ligeramente cuando pasamos el cursor sobre ellas.
Esto es porque cada control de imagen tiene asociado un controlador de eventos MouseMove
que cambia la propiedad SpecialEffect. Este es el controlador de eventos MouseMove
de Image1 (los dems son idnticos).

Private Sub Image1_MouseMove(ByVal Button As Integer, _

ByVal Shift As Integer, ByVal X As Single, ByVal Y As
Single)
Call NoRaise
Image1.SpecialEffect = fmSpecialEffectRaised
End Sub

Este procedimiento invoca al procedimiento NoRaise, que desactiva el efecto especial de

relieve de cada control.

Private Sub NoRaise()

Dim ctl As Control
For Each ctl In Controls
ctl.SpecialEffect = fmSpecialEffectFlat
Next ctl
End Sub

El efecto final es que el usuario consigue cierta informacin visual cuando el cursor pasa sobre
el control, como sucedera con una barra de herramientas de verdad. Sin embargo, esto es
todo lo que da de s la simulacin de la barra de herramientas. No es posible cambiar el
tamao del UserForm (por ejemplo, hacer que las imgenes se muestren verticalmente en
lugar de horizontalmente). Y, por supuesto, tampoco es posible acoplar nuestra barra de
herramientas a uno de los bordes de la ventana de Excel.
Un UserForm de tamao ajustable

Excel utiliza varios cuadros de dilogo de tamao ajustable. Por ejemplo, puede cambiarse el
tamao del cuadro de dilogo Administrador de nombres si hacemos clic en la esquina inferior
derecha y arrastramos.

Si queremos crear un UserForm de tamao ajustable, pronto descubriremos que no hay una
forma de hacerlo directamente. Una solucin es recurrir a las llamadas de la API de Windows.
El mtodo funciona, pero es complicado de configurar. En esta seccin veremos una tcnica
ms sencilla para crear un UserForm de tamao ajustable.

El siguiente dibujo muestra el UserForm descrito en esta seccin. Contiene un control de

cuadro de lista que muestra los datos de una hoja. Observamos las barras de desplazamiento
del cuadro de lista. Esto quiere decir que hay ms informacin de la que se puede ver.
Tambin observamos la esquina inferior derecha del cuadro de dilogo. Muestra un control de
tamao que probablemente nos resulte familiar.

Las imgenes que se muestran son

caracteres de la fuente Wingding. Para
introducir el carcter en una celda
seleccionamos en Excel
Insertar>Texto>Smbolo. Despus lo
copiamos al portapapeles y los pegamos en
la propiedad Picture en la ventana
Propiedades. Esta es una forma rpida y
sencilla de insertar imgenes a los controles
de los UserForm.

Al arrastrar la esquina inferior derecha

observamos que el cuadro de lista tambin
aumenta o disminuye su tamao junto con el del UserForm y que el botn Cerrar se mantiene
en la misma posicin relativa. Podemos aumentar el tamao del UserForm hasta los lmites del
monitor. Un UserForm puede tener un ancho y alto mximo de 12.287,25 unidades. La altura
mnima es de 25.75 unidades (igual que la altura de la barra de ttulo), y el ancho mnimo es de
105 unidades.

El truco est aqu en el control de etiqueta, que se agrega al UserForm en tiempo de ejecucin.
El control de tamao en la esquina inferior derecha es en realidad un control de etiqueta que
muestra la letra O (carcter 111) de la fuente Marlett (grupo de caracteres 2). Este control,
llamado objResizer, se agrega al UserForm en el procedimiento
UserForm_initialize:

Private Sub UserForm_Initialize()

' Agrega el control de tamao al formulario
Set objResizer = Me.Controls.Add("Forms.label.1",
MResizer, True)
With objResizer
 With .Font
.Name = "Marlett"
.Charset = 2
.Size = 16
.Bold = True
End With
.BackStyle = fmBackStyleTransparent
.AutoSize = True
.BorderStyle = fmBorderStyleNone
.Caption = "o"
.MousePointer = fmMousePointerSizeNWSE
.ForeColor = RGB(100, 100, 100)
.ZOrder
.Top = Me.InsideHeight - .Height
.Left = Me.InsideWidth - .Width
End With
End Sub

Esta tcnica se basa en los siguientes hechos:

El usuario puede mover un control de un UserForm, como vimos anteriormente.

Existen eventos que pueden identificar los movimientos del ratn y las coordenadas
del cursor. Nos referimos a MouseDown y MouseMove.
El cdigo VBA puede cambiar el tamao de un UserForm en tiempo de ejecucin, pero
un usuario no puede.

Si estudiamos estos hechos de manera creativa, eremos que es posible traducir los
movimientos del usuario de un control de etiqueta en informacin que se puede utilizar para
ajustar el tamao de un UserForm.

Cuando un usuario hace clic en el objeto de etiqueta objResizer, se ejecuta el

procedimiento que controla los eventos objResizer_MouseDown:

Private Sub objResizer_MouseDown(ByVal Button As Integer, _

ByVal Shift As Integer, ByVal X As Single, ByVal Y As
Single)
If Button = 1 Then
LeftResizePos = X
TopResizePos = Y
End If
End Sub

Este procedimiento se ejecuta nicamente si el botn izquierdo del ratn est presionado (es
decir, el argumento Button es 1) y el cursor est en la etiqueta objResizer. Las
coordenadas X e Y del ratn se almacenan en las variables de mdulo LeftResizePos y
TopResizePos.

Los movimientos posteriores del ratn inician el evento MouseMove, y el controlador de

eventos objResizer_MouseMove se pone en accin. Esta es una versin inicial de este
procedimiento:
 Private Sub objResizer_MouseMove(ByVal Button As _
Integer, ByVal Shift As Integer, ByVal X As Single, ByVal Y
As Single)
If Button = 1 Then
With objResizer
.Move .Left + X - LeftResizePos, .Top + Y -
TopResizePos
Me.Width = Me.Width + X - LeftResizePos
Me.Height = Me.Height + Y - TopResizePos
.Left = Me.InsideWidth - .Width
.Top = Me.InsideHeight - .Height
End With
End If
End Sub

Si estudiamos el cdigo, veremos que las propiedades Width y Height se ajustan basndose
en el movimiento del control de etiqueta objResizer.

El problema del dibujo anterior, desde luego, es que el otro control del UserForm no responde
al nuevo tamao del UserForm. Debera expandirse el cuadro de lista, y debera cambiar la
posicin del botn de comando para que permanezca en la esquina inferior derecha.

Es necesario ms cdigo VBA para ajustar los controles del UserForm cuando se modifica su
tamao. Escribiremos este cdigo nuevo en el procedimiento controlador de eventos
objResizerMouseMove. La siguiente declaracin se encarga de ello:

' Ajusta el cuadro de lista

On Error Resume Next
With ListBox1
.Width = Me.Width - 22
.Height = Me.Height - 100
End With
On Error GoTo 0
 'Ajusta el botn Cerrar
With CloseButton
.Left = Me.Width - 70
.Top = Me.Height - 54
End With

Estos dos controles se ajustan en relacin al tamao del UserForm (es decir, Me). Despus de
insertar este cdigo nuevo, el cuadro de dilogo funciona sin problemas. El usuario lo puede
aumentar como necesite, y los controles se ajustan al tamao.

La parte que presenta un mayor desafo al crear un cuadro de dilogo de tamao ajustable es
lograr que los controles se ajusten. Cuando tenemos ms de uno o dos controles las cosas se
pueden complicar bastante.

Controlar varios botones de UserForm con un controlador de

eventos

Cada botn de comando de un UserForm debe tener su propio procedimiento para controlar
sus eventos. Por ejemplo, si tenemos dos botones de comando, necesitaremos al menos dos
procedimientos de control de eventos.

Private Sub CommandButton1_Click()

' Aqu va el cdigo
End Sub

Private Sub CommandButton2_Click()

' Aqu va el cdigo
End Sub

En otras palabras, no se puede asignar una macro para que se ejecute cuando se haga clic en
cualquier botn de comando. Cada controlador de eventos Click est conectado a su botn
de comando. Sin embargo, podemos hacer que cada controlador de eventos llame a otra
macro que los incluya a todos en los procedimientos de control de eventos, pero tendremos
que pasar el argumento que indique en qu botn se hizo clic. En los siguientes ejemplos, al
hacer clic en CommandButton1 o CommandButton2 se ejecuta el procedimiento
ButtonClick y el nico argumento indica al procedimiento ButtonClick en qu botn
se hizo clic.

Private Sub CommandButton1_Click()

Call ButtonClick(1)
End Sub

Private Sub CommandButton2_Click()

Call ButtonClick(2)
End Sub
Si su UserForm tiene muchos botones de comando, configurar estos procedimientos de
control de eventos puede ser muy laborioso. Muchas personas preferirn tener un nico
procedimiento que pueda determinar en qu botn se hizo clic y realizar la accin apropiada.

Esta seccin describe una forma de eliminar esta limitacin utilizando un mdulo de clase para
definir una nueva clase.

Los siguientes pasos describen cmo crear el ejemplo de UserForm que se muestra a
continuacin:

1. Creamos el UserForm de la forma habitual y aadimos varios botones de comando

(este ejemplo tiene 16 botones). El ejemplo asume que el formulario se llama
UserForm1.
2. Insertamos un mdulo de clase en el proyecto (utilizamos Insertar>Mdulo de clase),
lo llamamos BtnClass e introducimos el siguiente cdigo. Tendremos que
personalizar el procedimiento ButtonGroup_Click.

Private Sub ButtonGroup_Click()

Dim Msg As String

Msg = "Usted hizo clic en " & ButtonGroup.Name & vbCrLf

& vbCrLf
Msg = Msg & "Nombre: " & ButtonGroup.Caption & vbCrLf
Msg = Msg & "Posicin izquierda: " & ButtonGroup.Left &
vbCrLf
Msg = Msg & "Posicin superior: " & ButtonGroup.Top
MsgBox Msg, vbInformation, ButtonGroup.Name
End Sub

3. Insertamos un mdulo de VBA estndar e introducimos el siguiente cdigo. Esta rutina

simplemente muestra el UserForm.

Sub ShowDialog()
UserForm1.Show
End Sub
 4. En el mdulo de cdigo para el UserForm, introducimos el siguiente procedimiento
UserForm_Initialize. Este procedimiento lo inicia el evento Initialize del
UserForm. Observamos que el cdigo excluye un botn llamado OKButton del grupo
de botones. Por lo tanto, hacer clic en el botn Aceptar no har que se ejecute el
procedimiento ButtonGroup_Click.

Private Sub UserForm_Initialize()

Dim ButtonCount As Integer
Dim ctl As Control

' Crea los objetos Button

ButtonCount = 0
For Each ctl In UserForm1.Controls
If TypeName(ctl) = "CommandButton" Then
If ctl.Name <> "OKButton" Then 'Omite el _
OkButton
ButtonCount = ButtonCount + 1
ReDim Preserve Buttons(1 To ButtonCount)
Set Buttons(ButtonCount).ButtonGroup = ctl
End If
End If
Next ctl
End Sub
Tras realizar estos pasos, podemos ejecutar el procedimiento ShowDialog para mostrar el
UserForm. Haciendo clic en cualquiera de los botones de comando (excepto en Aceptar) se
ejecuta el procedimiento ButtonGroup_Click.
Seleccionar un color en un UserForm

El ejemplo de esta seccin es una funcin que muestra un cuadro de dilogo (la idea es similar
a la funcin MsgBox, pero un poco ms complejo). La funcin, llamada GetAColor, devuelve un
valor de color:

Function GetAColor() As Variant

UserForm1.Show
GetAColor = ColorValue
End Function

Podemos utilizar la funcin GetAColor con una instruccin como la siguiente:

UserColor = GetAColor ()

Ejecutar esta instruccin muestra el UserForm. El usuario selecciona un color y hace clic en
Seleccionar color. A continuacin, la funcin asigna el valor del color que ha seleccionado el
usuario a la variable UserColor.

El siguiente dibujo muestra el UserForm que contiene tres controles de barra de

desplazamiento, uno por cada color de la paleta de color del libro. El valor de cada barra de
desplazamiento va desde 0 a 255.

El UserForm GetAColor tiene otro detalle: recuerda el ltimo color seleccionado. Cuando la
funcin finaliza, los tres valores de la barra de desplazamiento se almacenan en el registro de
Windows, con el siguiente cdigo (APPNAME es una cadena definida en Module1):

SaveSetting APPNAME, "Colors", "RedValue", _

ScrollBarRed.Value
SaveSetting APPNAME, "Colors", "BlueValue", _
ScrollBarBlue.Value
SaveSetting APPNAME, "Colors", "GreenValue", _
ScrollBarGreen.Value
El procedimiento UserForm_initialize recupera estos valores y los asigna a las barras
de desplazamiento.

ScrollBarRed.Value = GetSetting(APPNAME, "Colors", _

"RedValue", 128)
ScrollBarGreen.Value = GetSetting(APPNAME, "Colors", _
"GreenValue", 128)
ScrollBarBlue.Value = GetSetting(APPNAME, "Colors", _
"BlueValue", 128)

El ltimo argumento de la funcin GetSetting es el valor predeterminado, que se utilizar

en caso de no encontrar la clave del registro. En este caso, cada color predeterminado ser
128, lo que genera una tonalidad de gris.

Las funciones SaveSetting y GetSetting siempre utilizan esta clave del registro:

HKEY_CURRENT_USER\Software|VB and VBA Program Settings\

Mostrar un grfico en un UserForm

Curiosamente, no hay una forma directa de mostrar un grfico en un UserForm. Por supuesto,
podemos copiar el grfico y pegarlo en la propiedad Picture de un control de imagen, pero
esto crea una imagen esttica del grfico y no mostrar ningn cambio que realicemos en l.

Esta seccin describe cmo mostrar un grfico en un UserForm. El siguiente dibujo muestra un
UserForm con un grfico que se muestra como un objeto de imagen. El grfico en realidad se
encuentra en una hoja y el UserForm siempre muestra el grfico actual. Esta tcnica funciona
copiando el grfico a un archivo de grficos temporal y despus, con la funcin
LoadPicture, especificamos el archivo temporal de la propiedad Picture del control de
imagen.
Pasos generales para mostrar un grfico en un UserForm
Para mostrar un grfico en un UserForm, seguimos estos pasos generales:

1. Creamos un grfico de la forma habitual.

2. Insertamos un UserForm y aadimos un control de imagen.
3. Escribimos cdigo de VBA para guardar el grfico como archivo gif y luego asignamos
el archivo gif a la propiedad Picture del control de imagen. Para ello tenemos que
utilizar la funcin de VBA LoadPicture.
4. Aadimos otros elementos embellecedores a nuestro gusto. Por ejemplo, el UserForm
del archivo de la demostracin contiene controles que nos permiten cambiar el tipo de
grfico. Alternativamente, podemos escribir cdigo para mostrar varios grficos.

Guardar un grfico como archivo gif

El siguiente cdigo muestra cmo crear un archivo gif llamado temp.gif) a partir de un grfico
(en este caso, el primer objeto grfico de una hoja llamada Datos).

Set currentChart = Sheets("Datos").ChartObjects(1).Chart

Fname = Application.DefaultFilePath &
Application.PathSeparator & "temp.gif"
CurrentChart.Export Filename:=Fname, FilterName:="GIF"

Cambiar la propiedad Picture del control de imagen

Si el control de imagen del UserForm se llama Image1, la siguiente instruccin carga la imagen
(representada por la variable Fname) en el control de imagen:

Image1.Picture = LoadPicture(Fname)

Si desea obtener ms ejemplos de UserForms o aprender otras tcnicas con VBA le invitamos a
visitar nuestra web, http://www.ayudaexcel.com, donde encontrar la coleccin ms completa
de ejemplos con VBA, plantillas, manuales, trucos y academias donde se imparten cursos de
Excel.