Add Utils.Conversions unit & tests to DUnitX tests

delphidabbler · delphidabbler · commit fa75efb4620e · 2024-10-08T13:06:09.000+01:00
diff --git a/cupola/src/CSLE.Utils.Conversions.pas b/cupola/src/CSLE.Utils.Conversions.pas
@@ -0,0 +1,33 @@
+{
+  This Source Code Form is subject to the terms of the Mozilla Public License,
+  v. 2.0. If a copy of the MPL was not distributed with this file, You can
+  obtain one at https://mozilla.org/MPL/2.0/
+
+  Copyright (C) 2024, Peter Johnson (gravatar.com/delphidabbler).
+
+  Various conversion routines.
+}
+
+unit CSLE.Utils.Conversions;
+
+interface
+
+function TryStrToUint16(const AStr: string; out Value: UInt16): Boolean;
+
+implementation
+
+uses
+  System.SysUtils;
+
+function TryStrToUInt16(const AStr: string; out Value: UInt16): Boolean;
+begin
+  var IntValue: Integer;
+  if not TryStrToInt(AStr, IntValue) then
+    Exit(False);
+  if (IntValue < 0) or (IntValue > High(UInt16)) then
+    Exit(False);
+  Value := UInt16(IntValue);
+  Result := True;
+end;
+
+end.
diff --git a/cupola/tests/CodeSnip.Cupola.Tests.dpr b/cupola/tests/CodeSnip.Cupola.Tests.dpr
@@ -12,7 +12,9 @@ uses
   DUnitX.Loggers.Console,
   DUnitX.Loggers.Xml.NUnit,
   {$ENDIF }
-  DUnitX.TestFramework;
+  DUnitX.TestFramework,
+  CSLE.Utils.Conversions in '..\src\CSLE.Utils.Conversions.pas',
+  Test.Utils.Conversions in 'Test.Utils.Conversions.pas';
 
 {$IFNDEF TESTINSIGHT}
 var
diff --git a/cupola/tests/CodeSnip.Cupola.Tests.dproj b/cupola/tests/CodeSnip.Cupola.Tests.dproj
@@ -69,6 +69,8 @@
         <DelphiCompile Include="$(MainSource)">
             <MainSource>MainSource</MainSource>
         </DelphiCompile>
+        <DCCReference Include="..\src\CSLE.Utils.Conversions.pas"/>
+        <DCCReference Include="Test.Utils.Conversions.pas"/>
         <BuildConfiguration Include="Base">
             <Key>Base</Key>
         </BuildConfiguration>
@@ -103,6 +105,7 @@
                     </Platform>
                 </DeployFile>
                 <DeployFile LocalName="Win32\Debug\CodeSnip.Cupola.Tests.exe" Configuration="Debug" Class="ProjectOutput"/>
+                <DeployFile LocalName="Win32\Debug\CodeSnip.Cupola.Tests.exe" Configuration="Debug" Class="ProjectOutput"/>
                 <DeployClass Name="AdditionalDebugSymbols">
                     <Platform Name="iOSSimulator">
                         <Operation>1</Operation>
diff --git a/cupola/tests/Test.Utils.Conversions.pas b/cupola/tests/Test.Utils.Conversions.pas
@@ -0,0 +1,82 @@
+{
+  This unit is dedicated to public domain under the CC0 license.
+  See https://creativecommons.org/public-domain/cc0/
+}
+
+unit Test.Utils.Conversions;
+
+interface
+
+uses
+  DUnitX.TestFramework,
+
+  System.SysUtils,
+
+  CSLE.Utils.Conversions;
+
+type
+  [TestFixture]
+  TTestConversionRoutines = class
+  public
+    [Setup]
+    procedure Setup;
+    [TearDown]
+    procedure TearDown;
+
+    [Test]
+    [TestCase('0','0,0')]
+    [TestCase('42','42,42')]
+    [TestCase('Max','65535,65535')]
+    [TestCase('Plus 56','+56,56')]
+    [TestCase('Hex','$face,64206')]
+    procedure TryStrToUInt16_succeeds_on_strings_valid_valid_UInt16_values(const Str: string; Expected: UInt16);
+    [Test]
+    [TestCase('Empty str','')]
+    [TestCase('Punctuation','*&^%$')]
+    [TestCase('Letters','FooBar')]
+    [TestCase('Digits then letters','999aaa')]
+    procedure TryStrToUInt16_fails_on_non_numeric_strings(const Str: string);
+    [Test]
+    [TestCase('-1','-1')]
+    [TestCase('Max+1','65536')]
+    [TestCase('Massive +ve','68719476720')]
+    [TestCase('Massive -ve','-68719476720')]
+    procedure TryStrToUInt16_fails_on_strings_with_out_of_bounds_values(const Str: string);
+  end;
+
+implementation
+
+procedure TTestConversionRoutines.Setup;
+begin
+end;
+
+procedure TTestConversionRoutines.TearDown;
+begin
+end;
+
+procedure TTestConversionRoutines.TryStrToUInt16_fails_on_non_numeric_strings(const Str: string);
+begin
+  var Value: UInt16;
+  Assert.IsFalse(TryStrToUint16(Str, Value));
+end;
+
+procedure TTestConversionRoutines.TryStrToUInt16_fails_on_strings_with_out_of_bounds_values(
+  const Str: string);
+begin
+  var Value: UInt16;
+  Assert.IsFalse(TryStrToUint16(Str, Value));
+end;
+
+procedure TTestConversionRoutines.TryStrToUInt16_succeeds_on_strings_valid_valid_UInt16_values(
+  const Str: string; Expected: UInt16);
+begin
+  var Actual: UInt16;
+  var Res := TryStrToUint16(Str, Actual);
+  Assert.IsTrue(Res, 'Returns True');
+  Assert.AreEqual(Expected, Actual, 'Value');
+end;
+
+initialization
+  TDUnitX.RegisterTestFixture(TTestConversionRoutines);
+
+end.
