User:Erfurth/Dresdner Hefte

Wartungslisten

• 100er Hefte: [1]

• Improve series: Dresdner Hefte (Q14916674) auf Wikidata:Scholia/de: Missing author items and main topics

#Dresdner Hefte als Übersicht nach Ausgabenr.
SELECT ?item ?itemLabel ?pubdate ?k10 ?issue
WHERE 
{
  ?item wdt:P31 wd:Q16324495.
  ?item wdt:P1433 wd:Q14916674.
  ?item wdt:P433 ?issue.
  ?item wdt:P577 ?pubdate.
  optional {
    ?item wdt:P6721 ?k10.
    }
  minus{
    ?item wdt:P6721 [].
    }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de". } 
} ORDER BY ?pubdate

Try it!

SQL

SELECT ?sql
WHERE 
{
  ?item wdt:P31 wd:Q16324495. 
  ?item wdt:P1433 wd:Q14916674.
  ?item wdt:P433 ?issue.
  ?item wdt:P577 ?pubdate.
  BIND(concat("update ddhe set pubdate='",str(YEAR(?pubdate)),'-',str(MONTH(?pubdate)),'-',str(DAY(?pubdate)),"' where id=",str(?issue),';') as ?sql )
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de". } 
}

Try it!

select concat('CREATE',char(10),'LAST',char(9),'Lde',char(9),'"',label,'"',char(10),'LAST',char(9),'Dde',char(9),'"',description,'"',char(10),'LAST',char(9),'P17',char(9),P17,char(10),'LAST',char(9),'P31',char(9),P31,char(10),'LAST',char(9),'P123',char(9),P123,char(10),'LAST',char(9),'P179',char(9),P179,char(10),'LAST',char(9),'P972',char(9),P972,char(10),'LAST',char(9),'P1813',char(9),'de:"',shortname,'"',char(10),'LAST',char(9),'P1433',char(9),P1433,char(10),'LAST',char(9),'P1476',char(9),P1476) from logdb.ddhe where wd=

Register für Zeitperioden

SELECT ?item ?itemLabel ?schlagwort ?schlagwortLabel ?Epoche WHERE {
  ?item wdt:P1433 wd:Q14916674;
    p:P921 ?mainSubStmt.
  ?mainSubStmt ps:P921 ?schlagwort.
  OPTIONAL {
    ?mainSubStmt prov:wasDerivedFrom ?refNode.
    ?refNode pr:P1932 ?DDH_EpocheCode;
      pr:P248 wd:Q14916674.
    BIND(
      IF(STRSTARTS(?DDH_EpocheCode, "D "), "1764 bis 1831",
      IF(STRSTARTS(?DDH_EpocheCode, "E "), "1832 bis 1871", "")) 
     AS ?Epoche)
  }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}

Try it!

Wartungslisten (Snippets)

history of...:

#main subjects "history of" (from Gartenlaube)
SELECT ?subject ?theme ?thema
WHERE 
{
  ?item wdt:P1433 wd:Q655617.
  ?item wdt:P921 ?subject.
  ?subject rdfs:label ?thema filter (lang(?thema) = "de").
  ?subject rdfs:label ?theme filter (lang(?theme) = "en").
  FILTER( CONTAINS( ?theme, "history" )).
} GROUP BY ?subject ?theme ?thema

Try it!

#1lib1ref:

#create Literature-Snippets from @ddhefte WD items with WP sitelink
SELECT ?subject ?subjectLabel ?heft ?heftLabel ?item ?itemLabel ?pl ?sitelink ?snippet
WHERE 
{
  ?heft wdt:P1433 wd:Q14916674.
  ?item wdt:P1433 ?heft.
  ?heft wdt:P1476 ?hefttitle.
  ?heft wdt:P433 ?issue.
  ?heft wdt:P98  ?editor.
  ?heft wdt:P212 ?isbn13.
  ?heft wdt:P577 ?published.
  ?editor rdfs:label ?el filter (lang(?el) = "de").
  ?item wdt:P304 ?pages.
  ?item wdt:P50 ?author.
  ?author rdfs:label ?al filter (lang(?al) = "de").
  ?item wdt:P1476 ?title.
  ?item wdt:P921 ?subject.
  optional {
    ?item wdt:P5008 ?project.
    ?project rdfs:label ?pl filter (lang(?pl) = "de").
  }
  ?subject wdt:P31 wd:Q5.
  ?sitelink schema:about ?subject .
  ?sitelink schema:isPartOf <https://de.wikipedia.org/>.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
  BIND(CONCAT("'"`UNIQ--ref-0000000E-QINU`"'") as ?snippet)
}

Try it!

Übersichten

• Personen-Graph:

#defaultView:Graph
SELECT DISTINCT ?item ?itemLabel ?pic1 ?linkTo ?linkToLabel ?pic2
WHERE {
  ?item wdt:P1433 wd:Q14916674.
  ?item wdt:P921 ?linkTo. # Person als zentrales Thema
  ?linkTo wdt:P31 wd:Q5
  OPTIONAL { ?item wdt:P18 ?pic1 }
  OPTIONAL { ?linkTo wdt:P18 ?pic2 }
  SERVICE wikibase:label {bd:serviceParam wikibase:language "de" }
}

Try it!

• Zeitstrahl:

#defaultView:Timeline
SELECT DISTINCT ?item ?shortname ?cover ?date
WHERE {
  ?item wdt:P1433 wd:Q14916674.
  ?item wdt:P1813 ?shortname.
  ?item wdt:P577 ?date.
  ?item wdt:P18 ?cover.
  SERVICE wikibase:label {bd:serviceParam wikibase:language "de" }
}

Try it!

• • als VALUES-Abfrage

SELECT ?item ?itemLabel ?datum
  WHERE {
  VALUES (?inceptions) {
    (wd:Q111709160)   # Verein für Geschichte und Topographie Dresdens und seiner Umgebung
    (wd:Q111243259)   # Verein für Geschichte Dresdens
    (wd:Q35906273)    # Dresdner Geschichtsverein
                      # Forschungsgruppe zur Kulturgeschichte des Dresdner Raumes
                      # weitere Ereignisse, Redakteure, Autoren und Hefte dann per UNION
  }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de" }
  BIND(?inceptions as ?item) .
  ?item wdt:P571 ?datum.
} ORDER BY ?datum

Try it!

• Alle Artikel als Tree mit zentralem Thema:

#Uebersicht Dresdner Hefte in Wikidata, Anzeige als Tree
#item: Artikel im Dresdner Heft, heft: DDHeft
#defaultView:Tree
SELECT ?heft ?shortname ?item ?itemLabel ?subject ?subjectLabel WHERE {
    ?item wdt:P1433 wd:Q14916674.
    ?item wdt:P1433 ?heft.
    ?heft wdt:P1813 ?shortname.
    ?heft wdt:P577 ?pubdate.
     ?item wdt:P921 ?subject.
     SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],de"}
} ORDER BY ?pubdate

Try it!

• Anzeige auf Karte

#Uebersicht Artikel Dresdner Hefte in Wikidata, Anzeige als Karte
#subject: Zentrales Thema des Artikels
#defaultView:Map
SELECT ?item ?itemLabel ?subject ?subjectLabel ?coord WHERE {
    ?item wdt:P1433 wd:Q14916674.
    ?item wdt:P921 ?subject.
    ?subject wdt:P625 ?coord.
    SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],de"}
}

Try it!

Autoren

• Berufe der Autoren

Variante 1: Autoren heute

#Uebersicht Berufe, Anzeige als BubbleChart
#author= Autor des Artikels im DDHeft 
#occupation= Tätigkeit des Autors
#defaultView:BubbleChart
SELECT ?occupationLabel (count(*) as ?count) WHERE {
    ?item wdt:P1433 wd:Q14916674.
    ?item wdt:P50 ?author.
    ?author wdt:P106 ?occupation.
     SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],de"}
} GROUP BY ?occupationLabel ?count ORDER BY DESC (?count)

Try it!

Variante 2: Mitglieder damals

#author= Autor des Artikels im DDHeft 
#occupation= Tätigkeit des Autors
#defaultView:BubbleChart
SELECT ?occupationLabel (count(*) as ?count) WHERE {
    ?author wdt:P463 wd:Q111243259.
    ?author wdt:P106 ?occupation.
     SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],de"}
} GROUP BY ?occupationLabel ?count ORDER BY DESC (?count)

Try it!

AQID

SELECT * WHERE {
  ?item wdt:P463 wd:Q111243259.
  ?item p:P463 ?mainSubjStmt. 
  ?mainSubjStmt prov:wasDerivedFrom ?refNode. 
  ?refNode pr:P854 ?refUrl.
}

Try it!