Wikidata talk:Database reports/without claims by site/frwiki

From Wikidata
Jump to navigation Jump to search
[edit]

Problèmes identifiés/identified issues

[edit]
Problèmes de quality de données du système des liens Wikibase/Wikibase sitelink data quality issues

A leur sujet en général/About these isuse in general: Wikidata:Report a technical problem#Resolve_data_quality issues of the sitelink system

Problèmes d'édition Wikidata/Wikidata editorial issues
  • création d'éléments en masse sans P31/bulk creations of items without P31
  • création d'éléments en masse avec doublons/bulk creations of items without de-duplication
  • Property_talk:P2671#lack_of_other_statements_on_items (items would generally have at least P31 or P279)
  • nouveaux éléments créées par Pibot/new items created by Pibot
    • ne s'applique pas à frwiki/not applicable to frwiki
Historique/historic
  • éléments créés en 2012-2013 avant qu'il y ait des déclarations/items created in 2012-2013 before statements were possible (is it?)

Requêtes/queries

[edit]

total

[edit]
#title:total
SELECT (COUNT(*) as ?count)
{
  ?item wikibase:statements 0 . 
  [] schema:about ?item ; schema:isPartOf <https://fr.wikipedia.org/> . 
}
total

liste/list

[edit]
#title:liste
SELECT *
{
  ?item wikibase:statements 0 ; wikibase:sitelinks ?sls .
  ?wiki schema:about ?item ; schema:isPartOf <https://fr.wikipedia.org/> ; schema:name ?n . 
}
liste

age des entrées/age of items

[edit]
#defaultView:AreaChart
#title:age of items
SELECT ?date ?cumulativecount 
{
    hint:Query hint:optimizer "None".
    {   SELECT ?milestonep (COUNT(?item) as ?cumulativecount)
        WHERE
        {
          { SELECT ?item { ?item wikibase:statements 0 . [] schema:about ?item ; schema:isPartOf <https://fr.wikipedia.org/> } }
          BIND( xsd:integer( substr(str(?item), 33)) as ?qid)
          wd:Q38074555 p:P1114 ?milestonep .
          ?milestonep ps:P1114 ?milestone 
          FILTER( ?milestone > ?qid ) 
        }
        GROUP BY ?milestonep
    }          
    ?milestonep pq:P585 ?date
}
age of items

màj manuelle/manual update

[edit]
#title:màj manuelle
SELECT ?id ?item ?wiki ?sls ?line
WHERE
{
  ?item wikibase:statements 0 .
  ?wiki schema:about ?item ; schema:isPartOf <https://fr.wikipedia.org/> ; schema:name ?n ; schema:inLanguage ?lang .
  hint:Prior hint:rangeSafe true .  
  BIND(strafter(str(?item),"Q") as ?id)  
  BIND(CONCAT("* [[Q",?id,"]] - [[:",?lang,":",?n,"]]") as ?line)
  ?item wikibase:sitelinks ?sls .
}
màj manuelle

nuage de mots-clés/wordcloud

[edit]
#title:wordcloud articles without statements MyLang Wikipedia (switch to "Table" view to list, at left border of screen)
#defaultView:BubbleChart
SELECT
  ?word
  (COUNT(*) as ?count) 
  (URI(CONCAT("https://www.wikidata.org/w/index.php?search=inlabel%3A",?word,"%40[AUTO_LANGUAGE]+-haswbstatement%3A%2A&profile=advanced&fulltext=1&ns=1")) as ?search)
WITH
{
  SELECT ?item (CONCAT(?n, " 1 1 1 1 1 1 1 1 ") as ?string) 
  {
    ?item wikibase:statements 0 .
    [] schema:about ?item ; schema:name ?n ; schema:isPartOf <https://[AUTO_LANGUAGE].wikipedia.org/>
  }
  LIMIT 20000
} as %aa
WITH
{
  SELECT (str(?nv-1) as ?ord) { [] wdt:P5176 ?i ; wdt:P1181 ?nv . FILTER( ?nv < 8) } 
} as %i  
WHERE
{
  INCLUDE %i
  INCLUDE %aa
  BIND(  CONCAT("^([^ ]+ ){",?ord,"}([^ ]+) .+$") as ?re)         
  BIND(  REPLACE(?string, ?re, "$2") as ?word)
  # FILTER( ?word != "1" && )
  FILTER( strlen(?word) > 4)           
} 
GROUP BY ?word
ORDER BY DESC(?count) 
LIMIT 100
wordcloud articles without statements MyLang Wikipedia (switch to "Table" view to list, at left border of screen)

P31 from page title begin

[edit]
#title:P31 déduit du début du titre de la page Wikipédia/P31 from page title begin
SELECT ?n ?item ?pref ?inst 
{
  VALUES ( ?pref ?inst ) { 
    ( "Modèle:" wd:Q11266439 )
    ( "Module:" wd:Q15184295 )
    ( "Catégorie:" wd:Q4167836 )
    ( "Projet:" wd:Q14204246 )    
    ( "Wikipédia:" wd:Q14204246 )  
    ( "Aide:" wd:Q56005592 )     
    ( "Liste de" wd:Q13406463 )  
    ( "Glossaire d" wd:Q859161 )      
    ( "Vocabulaire d" wd:Q859161 )
  }    
  ?item wikibase:statements 0 . 
  [] schema:about ?item ; schema:isPartOf <https://fr.wikipedia.org/> ; schema:name ?n . 
  FILTER( strstarts(?n , ?pref) ) 
}  
LIMIT 1000
P31 déduit du début du titre de la page Wikipédia/P31 from page title begin

P31 from page title ending

[edit]
#title:P31 déduit de la fin du titre de la page Wikipédia/P31 from page title ending
SELECT ?n ?item ?pref ?inst 
{
  VALUES ( ?suff ?inst ) { 
    ( "(film)" wd:Q11424 )    
    ( "prénom)" wd:Q202444 )  
    ( "chanson)" wd:Q7366 )     
    ( "(homonymie)" wd:Q4167410 )  
    ( "série télévisée)" wd:Q5398426 )
    ( "(album)" wd:Q482994 )
    ( "(rivière)" wd:Q4022 ) 
  }    
  ?item wikibase:statements 0 . 
  [] schema:about ?item ; schema:isPartOf <https://fr.wikipedia.org/> ; schema:name ?n . 
  FILTER( strends(?n , ?suff) ) 
}  
LIMIT 1000
P31 déduit de la fin du titre de la page Wikipédia/P31 from page title ending
Retrieved from "https://www.wikidata.org/w/index.php?title=Wikidata_talk:Database_reports/without_claims_by_site/frwiki&oldid=1544788371"